*********************************************************************************
*										*
*	    ,o888888o.    888888888888.   88888888888888 88888888888888		*
*	   8888     `88.  888888    `88.  888888         888888         	*
*	,888888       `8. 888888     `88  888888         888888         	*
*	8888888           888888     ,88  888888         888888         	*
*	8888888           888888.   ,88'  88888888888888 88888888888888 	*
*	8888888           888888888888'   888888         888888         	*
*	8888888           888888`8b       888888         888888         	*
*	`888888       .8' 888888 `8b.     888888         888888         	*
*	   8888     ,88'  888888   `8b.   888888         888888         	*
*	    `8888888P'    888888     `88. 88888888888888 88888888888888		*
*										*
*********************************************************************************
*******************************************************************************
**	DISCLAIMER
*******************************************************************************
**	This model is provided as is, where is, and with no warranty of any kind
**	either expressed or implied, including but not limited to any implied
**	warranties of merchantability and fitness for a particular purpose.
*******************************************************************************

***********************************************************
****	Wolfspeed SiC Schottky diode C6D05170H Spice Library
****	Version 1.0 Date: 12-06-2023
****
***********************************************************
****	Revision record
****	Version 1	Initial Release - Datasheet 10-2023
****
*********************************************************************************
.subckt C6D05170H A K Case Tj Tc

.param p11 = -55
.param p12 = 500

R101 Tr 0	1E6
E101 Tr 0 	value {limit(V(Tj),p11,p12)}

**************
*Schottky diode
**************
L_anode1	A	AD1	6n

xgAK	K	AD14	A	CAK_C6D05170H
D1	AD14	K	CPW6-1700-Z005A
Er1 	AD13 	AD14	value {(2.383n*V(Tr)**3+1.8u*V(Tr)**2+420.4u*V(Tr)+68.99m)*v(net1)}
Eth	AD12	AD13	value {Limit((-1.992n*V(Tr)**3+880.8n*V(Tr)**2-1.248m*V(Tr)+1.016),0,18)}
vdiode1	AD1	AD12	0

Esn1	net1	0	value {I(vdiode1)}
Rsn1	net1	0	1E6

R11	Case	K	0.1m
R11p	Case	K	0.1m

***********
*PiN diode2
***********

D2	AD4	K	PiN_CPW6-1700-Z005A
Rn2	AD3 	AD4	0.082
Eth2	AD2	AD3	value {Limit(-33.4m*V(Tr)+11.965,1,50)}
vdiode2	AD1 	AD2	0
Esn2	net2	0	value {I(vdiode2)}
Rsn2	net2	0	1E6
***********
*Breakdown voltage
***********
Ebd1	Ab1	A	value {Limit(189.1u*V(Tr)**2+289.2m*V(Tr)+1934.02,1900,1990)}
Dbd1	Ab2	Ab1	Bdown_CPW6-1700-Z005A
Ebd2	Ab3	Ab2	value {
+			If (I(vdiode3)>260u,
+			10*I(vdiode3)
+			,
+			1K*I(vdiode3)
+			)
+			}
vdiode3	K 	Ab3	0

RAK	A	K	65E6

**********************************************************
.model CPW6-1700-Z005A d(vfwd=0.05 ron=0)

.model PiN_CPW6-1700-Z005A d(vfwd=0.05 ron=0)

.model Bdown_CPW6-1700-Z005A d(vfwd=0.05 ron=1m)

**********************************************************

Gheat	0	Tj	value {abs(V(AD12,K)*v(net1))+abs(V(AD2,K)*v(net2))}

R0 N1 Tj 0.039907
R1 N2 N1 0.091216
R2 N3 N2 0.538626
R3 Tc N3 0.278759

C0 Tj 0 0.0002508
C1 N1 0 0.0010522
C2 N2 0 0.0035860
C3 N3 0 0.0337133

.ends C6D05170H

.subckt CAK_C6D05170H K AD14 A

.param Cjo = 646.25p
.param Vj  = 2.39
.param M   = 0.51

G12 K d1 value {
+	if(V(K,A)>0,
+		(Cjo/(1+(limit(v(K,A),0,400)/Vj)**M))*ddt(v(K,A));
+		,
+		0
+			)
+			}

R_CDS d1 AD14 1E-4

.ends CAK_C6D05170H
